Embedding Fonts In Actionscript 3

I hardly use the Flash IDE at all any more. Pretty much all of my coding is done in FlashDevelop. One thing that the IDE does very well is the embedding of fonts but there are certainly ways of doing it using purely code. People seem to have found many ways of embedding fonts but this one has always worked for me:

This class is my font library - I embed all fonts that I use in here. The two things to note are the embed code for the fonts and public constants to allow me to access them using FontLibrary.FONT...

package org.experimentalized.fonts 
{
 /**
  * Font Library
  * @author Experimentalized
  */
 public class FontLibrary 
 {
  //Embed your fonts here
  [Embed(source="samplefont.ttf",fontName = "Mia's Scriblings ~", mimeType = "application/x-font-truetype")]
  private static const _samplefont:String;
  
  //Access font using this
  public static const FONT_SAMPLE:String = "Mia's Scriblings ~";
 }
}

This is the main class of my application. Here I create a sample text field and set the text format to one of my embedded fonts.

package org.experimentalized.fonts 
{
 import flash.display.Sprite;
 import flash.text.TextField;
 import flash.text.TextFormat;
 
 public class Fonts_Demo extends Sprite 
 {  
  public function Fonts_Demo() 
  {
   //Create a new text field
   var text_field:TextField = new TextField();
   text_field.width = 500;
   text_field.height = 200;
   
   //Make sure we embed fonts
   text_field.embedFonts = true;
   
   //Create some text
   text_field.text = "This is a test";
      
   //Set the font using our new font library
   text_field.setTextFormat(new TextFormat(FontLibrary.FONT_SAMPLE, 30));
   
   //Add the text field to the display object list
   addChild(text_field);
  } 
 }
}

Easy! You can download all of the source files for this and my other projects from: http://experimentalized.com/blog/sourcezip/Blog.zip.